スクリプティング
チュートリアル

ラッピング

Scheme コマンドは低レベルで動作するため、単純なタスクでも複数の手順が必要になる場合があります。ただし、この粒度により柔軟性が得られ、必要なことを正確に実行する小さな再利用可能な関数にコマンドをバンドルできます。ラッピングは白黒つける概念ではありません。頻繁に使用されるコマンドの単純なエイリアスから、ワークフロー全体を管理するより複雑な関数まで多岐にわたります。ラッパーは、読みやすさを向上させるための単なる便利な関数である場合もありますが、複数の操作をカプセル化するフル機能のユーティリティに進化する場合もあります。

関数をラップする理由

関数をラップすることには、いくつかの重要な利点があります。

  • 繰り返しのタスクを簡素化 – 低レベルのコマンドを繰り返す代わりに、ヘルパー関数でラップして再利用します。
  • 可読性の向上 – ラップされた関数に明確でわかりやすい名前を付けることで、コードが一目で理解しやすくなります。
  • 複雑さをカプセル化 – 長く不可解なコマンド リスト、深くネストされたループ、複雑なメッセージ ステートメントを扱うのではなく、それらをより小さく、適切に構造化されたヘルパー関数に分割できます。
  • 保守性の向上 – コマンドのコア機能が変更された場合、ラップされた関数を 1 回更新するだけで済み、プラグインはそれらの変更の詳細から隔離されます。
  • コードの再利用を促進 – 各ヘルパーがライブラリの一部となり、今後のスクリプトの作成とデバッグが高速化されます。

プラグインが成長するにつれて、ラッパーはコアロジックを読みやすく保ち、反復的な詳細を分離するのに役立ちます。

関数をラップするもう 1 つの利点は、関数を Visual Studio Code のような構文ハイライターに統合できることです。これにより、読みやすさとナビゲーションが向上し、スクリプトがより明確になります。カスタム関数を使用するプラグインでは、緑色で強調表示された関数はライブラリから正しく参照されていることを示します。

独自のヘルパー ライブラリを管理する場合は、エディターの構文強調表示にプロジェクトの関数名を追加することを検討してください。これにより、ナビゲーションとリファクタリングが高速化されます。

例:

ランダムシード 

;; 目的: フィルターのシード用にランダムな整数を返す
(define (random-seed)
  (msrg-rand))

msrg-rand をコード内で直接使用することもできますが、random-seed という関数内にラップすると読みやすくなります。関数に明確でわかりやすい名前を付けると、その目的が一目で理解しやすくなります。

さらに、random-seed をスタンドアロン関数として定義すると、実装を 1 か所に集中させながら、プラグイン内のどこでも使用できるようになります。シードの生成方法を変更する必要がある場合は、この関数を更新するだけでよく、コードの残りの部分は変更しません。

たとえば、代わりに random に切り替えることにした場合:

;; 目的: フィルターのシード用にランダムな整数を返す
(define (random-seed)
  (random 1000))

関数名は同じままなので、スクリプトは変更せずに動作し続けることが保証されます。このアプローチにより、コードは柔軟で保守しやすく、読みやすくなります。

JPEG エクスポート

Scheme の JPEG エクスポート機能には多くのパラメーターが付属しており、画像の保存方法を細かく制御できます。ただし、ほとんどの場合、ファイル名や品質など、いくつかの重要な設定のみを気にします。プロセスを簡素化するために、関数をラップできます。

;; 目的: 画像を指定品質の JPEG として保存する
(define (file-jpg-save image file quality)
  (let ((export-file (if (has-substring? file ".jpg")
                         file
                         (string-append file ".jpg")))) ;; jpg.jpg を避ける
    (debug-message "Exporting: " export-file)
    (file-jpeg-export #:run-mode RUN-NONINTERACTIVE
                      #:image image
                      #:file export-file
                      #:options -1
                      #:quality (* 0.01 quality)
                      #:smoothing 0.0
                      #:optimize 1
                      #:progressive 1
                      #:cmyk 0
                      #:sub-sampling "sub-sampling-1x1"
                      #:baseline 1
                      #:restart 0
                      #:dct "integer")))

このラッパー関数では、エクスポート オプションのほとんどがハードコーディングされており、調整する可能性が高いパラメーター (ファイル名と品質) のみが公開されています。このアプローチにより、可読性が向上し、画像の保存が簡単になります。さらに、将来 Lumi のエクスポーターが変更された場合、JPEG をエクスポートするすべてのスクリプトを変更するのではなく、この 1 つの関数を更新するだけで済みます。

ラッパーの使用

プラグインで JPEG をエクスポートするには、ライブラリを組み込み、カスタム関数を呼び出すだけです。

(file-jpg-save image "/home/mark/pictures/my-picture" 85)

これにより、コードがクリーンで読みやすく、適応性に優れた状態に保たれると同時に、最小限の労力で効率的に JPEG をエクスポートできるようになります。

car の置き換え

car 関数は難解で、スクリプト エラーが発生しやすい場合があります。誤って car をベクトルまたはリスト以外の項目に適用すると、予期しない動作が発生する可能性があります。コードをより堅牢で読みやすくするために、この機能をより安全な関数でラップすることができます。

;; 目的: リストまたはベクターの最初の項目を返す。
;;          入力が無効または空の場合に警告する。
(define (first-item collection)
  (cond
    ;; 空でないリストを処理
    ((and (list? collection) (not (null? collection)))
     (list-ref collection 0))
    ;; 空でないベクトルを処理
    ((and (vector? collection) (> (vector-length collection) 0))
     (vector-ref collection 0))
    ;; 無効または空の入力
    (else
     (begin
       (warning-message "first-item: Expected a non-empty list or vector, but received: " collection)
       #f))))

この関数は、リストまたはベクトルの最初の項目を安全に取得すると同時に、無効な入力または空の入力が見つかった場合に役立つ警告を表示します。 car の代わりに first-item を使用することで、偶発的なエラーのリスクが軽減され、スクリプトの明確さが向上します。

このラッパーを使用する理由

  • スクリプトのクラッシュを防止 – car をリスト以外に適用することによって発生するエラーを回避します。
  • リストとベクトルの両方をサポート – 使いやすさをリストだけでなく拡張します。
  • 意味のある警告を提供します – 予期しない入力の問題のデバッグに役立ちます。
  • 可読性の向上 – 関数名はその目的を明確に伝えます。

このロジックを first-item にカプセル化することで、プラグインがより堅牢になり、保守が容易になります。もちろん、これは個人の好みによって異なりますが、car、caar、cadr、および同様の Scheme 関数を直接使用してもまったく問題がない場合もあります。

ラップされた関数をラップする

すでにラップされている関数をラップすると、可読性と保守性がさらに向上します。たとえば、pixel-coords (list 100 200) のような座標ペアを扱う場合、次のように使用できます。

(first-item pixel-coords)

x 座標を取得します。ただし、機能的ではありますが、表現力はあまり高くありません。代わりに、first-item をより適切な定義でラップして、意図をより明確にすることができます。

;; 目的: 読みやすさのため x 座標を返す
(define (x-coord pixel-coords)
  (first-item pixel-coords))

;; 目的: 読みやすさのため y 座標を返す
(define (y-coord pixel-coords)
  (second-item pixel-coords))

このアプローチを使用する理由

  • コードの明瞭性の向上 – 一般的なリスト アクセス関数を使用する代わりに、その目的を説明する関数を明示的に定義します。
  • 保守性の向上 – 座標表現が変更された場合 (リストの代わりにベクトルを使用するなど)、これらの小さな関数を更新するだけで済みます。
  • 一貫性の促進 – x-coord と y-coord を使用すると、スクリプトが読みやすくなり、一目で理解できるようになります。

ここでは、一般的な Scheme を記述する代わりに、次のようにします。

(car pixel-coords) ;; x 座標を取得
(cadr pixel-coords) ;; y 座標を取得

our Scheme には次のように記述できます。

(x-coord pixel-coords)
(y-coord pixel-coords)

低レベル関数を意味のある名前でラップすることで、より直感的にデータを操作できる方法が作成され、混乱や潜在的なエラーが軽減されます。

出荷されたラッパー: ユーティリティ標準ライブラリ

Lumi には、起動時に自動的にロードされる既製のラッパーのセットが同梱されているため、(load ...) を呼び出すことなく、任意のプラグインまたは Scheme コンソールで使用できます。これらのライブラリ (common.scm、files.scm、gegl.scm、images.scm、layers.scm、parasites.scm、および paths.scm) は、上記の例とまったく同じ原理に基づいて構築されています。つまり、低レベルの操作に明確な名前が付けられています。反復的なボイラープレートを非表示にし、基礎となるコマンドが変更された場合に更新できる単一の場所を提供します。たとえば、images.scm は生の PDB 呼び出しの読み取り可能なラッパーとして image-get-open-list を提供し、files.scm は string-append チェーンの繰り返しが必要となるパス構築ヘルパーを公開します。

ユーティリティ ブラウザ (ヘルプ → プログラミング → ユーティリティ ブラウザ) で、エクスポートされたすべての名前を参照し、その docstring を読み、どのライブラリからのものかを確認できます。これは大規模なラッピングの実践的なデモンストレーションであり、独自のヘルパー ライブラリを構築するときに借用できるパターンの有用なソースです。

結論

関数のラッピングは、Scheme 開発を簡素化し、スクリプトをより読みやすく、保守しやすく、堅牢にする強力な方法です。複雑さをカプセル化し、必要な詳細のみを公開することで、プラグインを作成するためのより構造化されたアプローチを作成します。

このアプローチから得られる重要なポイントは次のとおりです。

  • 繰り返しのタスクを簡素化 – 低レベルのコマンドを手動で繰り返す代わりに、再利用可能な関数を作成します。
  • コードの可読性の向上 – 適切な名前のラッパーにより、スクリプトが理解しやすくなります。
  • 複雑さをカプセル化 – 低レベルの詳細はラッパー内で処理され、メイン スクリプトをクリーンな状態に保ちます。
  • 保守性の向上 – コア機能が変更された場合、ラッパーを更新するだけでよく、ラッパーに依存するすべてのスクリプトを更新する必要はありません。
  • 再利用と一貫性を促進 – 関数の個人ライブラリは時間の経過とともに増加し、開発がより迅速かつ効率的になります。

関数ラッピングを一貫して使用することで、Scheme プラグインの作成方法を変革し、よりモジュール式で表現力豊かなスクリプト環境を作成できます。これらの原則を念頭に置いて、アプローチを改良し続け、特定のニーズを満たす、より効率的でカスタマイズされたバージョンの Scheme を開発できます。

次のステップ: スクリプト内で繰り返されるブロックを特定し、明確な名前を持つ小さなヘルパーを抽出します。

フィルタープラグインデバッグ